*  _______ _______ _______ _______ _______ _______ ______  _______ _______ ______   _______
* |   _   |  _    |   _   |       |       |   _   |      ||   _   |  _    |    _ | |   _   |
* |  |_|  | |_|   |  |_|  |    _  |       |  |_|  |  _    |  |_|  | |_|   |   | || |  |_|  |
* |       |       |       |   |_| |       |       | | |   |       |       |   |_||_|       |
* |       |  _   ||       |    ___|      _|       | |_|   |       |  _   ||    __  |       |
* |   _   | |_|   |   _   |   |   |     |_|   _   |       |   _   | |_|   |   |  | |   _   |
* |__| |__|_______|__| |__|___|   |_______|__| |__|______||__| |__|_______|___|  |_|__| |__|
*                                                                        www.abapcadabra.com
*
*-------------------------------------------------------------------------------------------
* program          : ZABAPCADABRA_TVARVC_EDIT
* title            : Allow end user to create/change a TVARVC variabele
* functional area  : Cross modules
* environment      : 4.7
* program Function : This program demonstrates the use of the very powerful popup
*                    function module POPUP_GET_VALUES, implemented to allow
*                    editing a TVARVC variabele (the client dependant version of
*                    TVARV).
* Documentation    : Search for "Popups (accepting input)" on AbapcadabrA.com
* Previous version : This is the initial version
* Developer name   : Wim Maasdam
* Development date : 27/05/2015
* Version          : 0.1
*---------------------------------------------------------------------
* Change list:
*   Date       Description
*   27/05/2015 Initial release
*---------------------------------------------------------------------
report ZABAPCADABRA_TVARVC_EDIT.

tables: SSCRFIELDS. "Selection screen purpose only
*---------------------------------------------------------------------
*                                      S E L E C T I O N - S C R E E N
*---------------------------------------------------------------------
SELECTION-SCREEN FUNCTION KEY 1.

selection-SCREEN BEGIN OF LINE.
  selection-SCREEN COMMENT 1(23) lbl_01 FOR FIELD pa_file.
  PARAMETERS: pa_file TYPE C length 100 LOWER CASE visible length 50.
selection-SCREEN END OF LINE.
selection-SCREEN SKIP.
selection-SCREEN BEGIN OF LINE.
  SELECTION-SCREEN PUSHBUTTON (70)
    lbl_abca USER-COMMAND ABAPCADABRA
    VISIBLE LENGTH 5.
selection-SCREEN END OF LINE.

AT SELECTION-SCREEN.

  CASE SSCRFIELDS-UCOMM.
   when 'FC01'. "Function key 1...
     data: lt_SVAL type STANDARD TABLE OF SVAL,
           lw_SVAL type SVAL,
           lw_TVARVC type TVARVC,
           lv_returncode type c.

* Fetch date from the system:
     select single * from TVARVC into lw_TVARVC
       where name = 'ZHR_UPD_IT9003_FUTURE_KEY_DATE' and
             type = 'P' and "Parameter
             numb = 0000.
     if sy-subrc <> 0.
       clear: lw_TVARVC.
       lw_TVARVC-mandt = sy-mandt.
       lw_TVARVC-name = 'ZHR_UPD_IT9003_FUTURE_KEY_DATE'.
       lw_TVARVC-type = 'P'.
     endif.
     clear: lt_SVAL[], lw_SVAL.
     lw_SVAL-TABNAME = 'P0001'.
     lw_SVAL-FIELDNAME = 'BEGDA'.
     lw_SVAL-VALUE = lw_TVARVC-low.
     append lw_SVAL to lt_SVAL.
* Show  popup in which the future key date can be entered
     CALL FUNCTION 'POPUP_GET_VALUES'
       EXPORTING
         POPUP_TITLE           = 'Future key date'
       IMPORTING
         RETURNCODE            = lv_returncode
       TABLES
         FIELDS                = lt_SVAL
       EXCEPTIONS
         OTHERS                = 4.
     IF LV_RETURNCODE = 'A'.
       message 'Action cancelled' type 'S'.
     ELSE.
       read table lt_SVAL index 1 into lw_SVAL.
       lw_TVARVC-low = lw_SVAL-VALUE.
*----------------------------------------------------
* Update the TVARV variabele
       modify TVARVC from lw_TVARVC.
*----------------------------------------------------
       if sy-subrc <> 0.
         message 'Future key date change - UPDATE ERROR' type 'W'.
       else.
         message 'Future key date changed' type 'S'.
       endif.
     ENDIF.
* Link to documentation on AbapcadabrA
  WHEN 'ABAPCADABRA'.
    CALL FUNCTION 'CALL_BROWSER'
      EXPORTING
        URL                          = 'http://abapcadabra.com/index.php/screen-and-menu-painting/538-popups-accepting-input'
      EXCEPTIONS
        OTHERS                       = 0.
  ENDCASE.

*---------------------------------------------------------------------
* I N I T I T A L I Z A T I O N
*---------------------------------------------------------------------
INITIALIZATION.
* All texts for this report have been set up as hard-coded texts (no use
* of the report text-pool). Reason: easy copying of report source code.
lbl_abca = '@N5\QMore on AbapcadabrA.com@'.
lbl_01 = 'Unused parameter field'.
SSCRFIELDS-FUNCTXT_01 = 'Settings'.