*                _   _                               _       _           _
*               /_\ | |__   __ _ _ __   ___ __ _  __| | __ _| |__  _ __ /_\
*              //_\\| '_ \ / _` | '_ \ / __/ _` |/ _` |/ _` | '_ \| '__//_\\
*             /  _  \ |_) | (_| | |_) | (_| (_| | (_| | (_| | |_) | | /  _  \
*             \_/ \_/_.__/ \__,_| .__/ \___\__,_|\__,_|\__,_|_.__/|_| \_/ \_/
*                               |_|                      www.abapcadabra.com
*----------------------------------------------------------------------------
*  ____        _   _                _ _       _
* | __ ) _   _| |_| |_ ___  _ __   | (_)_ __ | | _____   Assistance programs
* |  _ \| | | | __| __/ _ \| '_ \  | | | '_ \| |/ / __|  to be called from
* | |_) | |_| | |_| || (_) | | | | | | | | | |   <\__ \  your report selection
* |____/ \__,_|\__|\__\___/|_| |_| |_|_|_| |_|_|\_\___/  screen: BLINKS !
*
*    AbapcadabrA Button Links: an AbapcadabrA trade mark product - FREE DOWNLOAD
*      Turn-key and ready to use functionality that can be made available
*      from a button on the selection screen of your report. There are a variety
*      of Button-link reports and this is one of them.
*      Find out MORE on AbapcadabrA.com - Search for "Button links"
*
* program          : ZABAPCADABRA_BLINK_BATCHJOBS
* title            : Batch jobs
* functional area  : Cross modules
* environment      : 4.7
* program Function : This report allows easy access to the SM37 transaction
* Documentation    : Search for "Button links" on AbapcadabrA.com
* Previous version : This is the initial version
* Developer name   : Wim Maasdam
* Development date : 01/10/2017
* Version          : 0.1
*---------------------------------------------------------------------
* Change list:
*   Date       Description
*   02/10/2017 Initial release
*
*---------------------------------------------------------------------
REPORT ZABAPCADABRA_BLINK_BATCHJOBS.

data: gt_bdcdata type standard table of bdcdata,
      gw_bdcdata type bdcdata,
      gv_time type t,
      gv_time_str type c length 8,
      gv_date type d,
      gv_date_str type c length 10.

* bdc_add 'X' 'PROGRAM_NAME' 'SCREEN NUMBER'.
* bdc_add ' ' 'FIELDNAME' 'FIELDVALUE'.
define bdc_add.
  clear gw_bdcdata.
  gw_bdcdata-dynbegin = &1.
  if &1 eq 'X'.
    gw_bdcdata-program = &2.
    gw_bdcdata-dynpro = &3.
  else.
    gw_bdcdata-fnam = &2.
    gw_bdcdata-fval = &3.
  endif.
  append gw_bdcdata to gt_bdcdata.
end-of-definition.

* When you call this report with a Submit - make sure you fill in  pa_BLINK with 'X'.
PARAMETERS pa_BLINK type c length 1 default space NO-DISPLAY.

SELECTION-SCREEN: BEGIN OF LINE, COMMENT 1(20) lbl_01 for field pa_JNAME MODIF ID kys.
PARAMETERS pa_JNAME type BTCH2170-JOBNAME DEFAULT '*' MODIF ID kys.
SELECTION-SCREEN: END OF LINE.
SELECTION-SCREEN: BEGIN OF LINE, COMMENT 1(20) lbl_02 for field pa_REPID MODIF ID kys.
PARAMETERS pa_REPID type SY-REPID DEFAULT '*' MODIF ID kys.
SELECTION-SCREEN: END OF LINE.

SELECTION-SCREEN SKIP.
SELECTION-SCREEN: BEGIN OF LINE, COMMENT 1(20) lbl_03,
  PUSHBUTTON 24(20) blbl_01 USER-COMMAND SM37_60,
  PUSHBUTTON 45(4) blbl_01b USER-COMMAND SM37_60b.
SELECTION-SCREEN: END OF LINE.
SELECTION-SCREEN: BEGIN OF LINE,
  PUSHBUTTON 24(20) blbl_02 USER-COMMAND SM37_240,
  PUSHBUTTON 45(4) blbl_02b USER-COMMAND SM37_240b.
SELECTION-SCREEN: END OF LINE.
SELECTION-SCREEN: BEGIN OF LINE,
  PUSHBUTTON 24(20) blbl_03 USER-COMMAND SM37_TODAY,
  PUSHBUTTON 45(4) blbl_03b USER-COMMAND SM37_TODAYb.
SELECTION-SCREEN: END OF LINE.
SELECTION-SCREEN: BEGIN OF LINE,
  PUSHBUTTON 24(20) blbl_04 USER-COMMAND SM37_OTHER.
SELECTION-SCREEN: END OF LINE.
SELECTION-SCREEN SKIP.
SELECTION-SCREEN: BEGIN OF LINE, POSITION 24.
  PARAMETERS pa_by_me as CHECKBOX.
SELECTION-SCREEN: COMMENT 26(22) lbl_04 FOR FIELD pa_by_me.
SELECTION-SCREEN: END OF LINE.


AT SELECTION-SCREEN OUTPUT.

  if pa_BLINK = abap_true.
    loop at screen.
      if screen-group1 = 'KYS'.
        screen-input = 0.
        screen-active = 0.
        modify screen.
      endif.
    endloop.
  endif.

AT SELECTION-SCREEN.

  case sy-ucomm(4).
    when 'SM37'.
      clear: gt_bdcdata[].
      bdc_add: 'X' 'SAPLBTCH' '2170',
               ' ' 'BTCH2170-JOBNAME' pa_JNAME,
               ' ' 'BTCH2170-PRELIM' 'X',
               ' ' 'BTCH2170-SCHEDUL' 'X',
               ' ' 'BTCH2170-READY' 'X',
               ' ' 'BTCH2170-RUNNING' 'X',
               ' ' 'BTCH2170-FINISHED' 'X',
               ' ' 'BTCH2170-ABORTED' 'X',
               ' ' 'BTCH2170-ABAPNAME' pa_REPID.

      if pa_by_me = abap_true.
        bdc_add: ' ' 'BTCH2170-USERNAME' sy-uname.
      else.
        bdc_add: ' ' 'BTCH2170-USERNAME' '*'.
      endif.

      case sy-ucomm.
        when 'SM37_60'.
          gv_time = sy-uzeit - 3600.
          write gv_time to gv_time_str using edit mask '__:__:__'.
          bdc_add: ' ' 'BTCH2170-FROM_TIME' gv_time_str,
                   ' ' 'BTCH2170-TO_TIME' '23:59:59',
                   ' ' 'BDC_OKCODE' '=DOIT'.
        when 'SM37_60B'.
          gv_time = sy-uzeit - 3600.
          write gv_time to gv_time_str using edit mask '__:__:__'.
          bdc_add: ' ' 'BTCH2170-FROM_TIME' gv_time_str,
                   ' ' 'BTCH2170-TO_TIME' '23:59:59'.
        when 'SM37_240'.
          gv_time = sy-uzeit - 14400.
          write gv_time to gv_time_str using edit mask '__:__:__'.
          bdc_add: ' ' 'BTCH2170-FROM_TIME' gv_time_str,
                   ' ' 'BTCH2170-TO_TIME' '23:59:59',
                   ' ' 'BDC_OKCODE' '=DOIT'.
        when 'SM37_240B'.
          gv_time = sy-uzeit - 14400.
          write gv_time to gv_time_str using edit mask '__:__:__'.
          bdc_add: ' ' 'BTCH2170-FROM_TIME' gv_time_str,
                   ' ' 'BTCH2170-TO_TIME' '23:59:59'.
        when 'SM37_TODAY'.
          bdc_add: ' ' 'BDC_OKCODE' '=DOIT'.
      endcase.

      call transaction 'SM37' using gt_bdcdata mode 'E'.

  endcase.

INITIALIZATION.
  lbl_01 = 'Jobname'.
  lbl_02 = 'Report/step'.

  lbl_03 = 'View batchjobs from'.
  blbl_01 = 'The past hour'.
  blbl_01b = '@MJ@'.
  blbl_02 = 'The past 4 hours'.
  blbl_02b = '@MJ@'.
  blbl_03 = 'Today'.
  blbl_03b = '@MJ@'.
  blbl_04 = 'Other'.
  lbl_04 = 'Started by me'.

START-OF-SELECTION.
  if pa_BLINK = abap_true.
    LEAVE PROGRAM.
  endif.